%*************************************************************************%
%                                READ.ISU                                 %
%*************************************************************************%

%  Indlæsning af data fra de to datafiler, dannelse af ISU datasæt OPG1.
%  Det forudsættes at de to datafiler 01-1-dat.txt og 01-1-da1.txt på
%  forhånd er kopieret til ISUW-arbejdsbiblioteket.

del
var ID S S1 S2 S3 S4 S5 ALDER forstaa huske 112
fac sex 112 2
fac text 112 5
fac randf 112 4
fac stud 112 3
open 01-1-dat.txt
skipline      { evt. skipline 2, hvis filen starter med en tom linie }
read ID S S1 S2 S3 S4 S5 text randf stud=,clm.com,lrerud,ha-mat \
sex=,mand,kvinde ALDER forstaa huske

var x1 x2 x3 x4 x5 x6 x7 x8 x9 x10 x11 x12 x13 x14 x15 x16 x17 x18 x19 112
open 01-1-da1.txt
skipline
read x1 x2 x3 x4 x5 x6 x7 x8 x9 x10 x11 x12 x13 x14 x15 x16 x17 x18 x19
save opg1


%*************************************************************************%
%                                RAN.ISU                                  %
%*************************************************************************%

%  Randomiseringstest. For at undersøge om der er en forskel mellem
%  mænds og kvinders scorer beregnes forskellen mellem gennemsnittene
%  for kvinder og mænd, først for selve datasættet (DIF) og derefter for
%  10000 datasæt der er fremkommet ved tilfældig ombytning af de 112
%  scorer.

del                 { alt ryddes }
get opg1            { data hentes }

focus sex 1
m1=mean(s)
includeall
focus sex 2
m2=mean(s)
includeall
dif=m2-m1           { = teststørrelsen for de oprindelige data }

nn=10000
var sim_dif nn

echo 0              { kommando- og meddelelsesekko slås fra }
out 0               { - for at slippe for 10000 advarsler }
ss=s                { kopi af s dannes, for en sikkerhed skyld }
var r 112           { skal bruges til sortering }
i=0                 { nulstilling af tællevariabel }

  %start
  i=i+1             { tæller 1 op }
  r=random          { r fyldes med ligefordelte tilfældige tal }
  sort r ss         { ss sorteres efter r, dvs. tilfældigt }
  focus sex 1
  m1=mean(ss)
  includeall
  focus sex 2
  m2=mean(ss)
  includeall
  sim_dif(i)=m2-m1  { = teststørrelsen for det i'te simulerede datasæt }
  goto %start i<nn  { løkken startes forfra hvis i<10000 }

del nn r ss i m1 m2 { oprydning, kun dif og sim_dif gemmes }
out                 { tilbage til default }
echo 1              { tilbage til default }

fac ekstrem 10000 2
ekstrem=2-(sim_dif>=dif)
onewaytable ekstrem

%  Når programmet har kørt (det taget lidt tid) får man resultatet af den
%  sidste kommando at se v.h.a. en SHOW kommando (outputfilen forevises).



%*************************************************************************%
%                             NORMHIST.ISU                                %
%*************************************************************************%
%    I forlængelse af bemærkninger ved forelæsningen 19/9 om det
%    uforsvarlige i at vurdere et histogram eller probitdiagram uden at
%    have noget at sammenligne med. NORMHIST kan bruges til at konstruere
%    sammenligningsgrundlaget.

%    Example: RUN NORMHIST 20 100 8
%    will produce 20 histograms of 100 pseudo-normal variables with the
%    vertical axis [-4,4] divided into 8 intervals.

        ECHO 0
        SUBST [Hist] [Obs] [Int]
        VAR $U [Obs]
        VAR $I 1
        $I=0
        FRAMETEXT Histogram for [Obs] normal observations
        XTEXT |

        %Label
        $I=$I+1
        $U=normal
        $U=$U-MEAN($U)
        $U=$U/SQRT(VARIANCE($U))
        HIST $U=-4.0,[Int],4
        GOTO %Label $I<[Hist]

        FRAMETEXT
        XTEXT
        ECHO 1



%*************************************************************************%
%                             OPG1LANG.ISU                                %
%*************************************************************************%
%  Indlæsning af "langt datasæt", som indeholder en observation pr.
%  (person,spørgsmål). Desværre kan dette datasæt ikke bruges til så
%  meget, da alle modeller vil blive forstyrret af at person-til-person
%  variationen er meget stor - og hvis man tager en personparameter med
%  i sine modeller bliver alle interessante parametre ikke-estimable
%  (tekst, køn, alder, studium, randf osv. er knyttet til personer)

  del
  n=112*19      { = antal personer gange antal spørgsmål }
  var x n
  open 01-1-da1.txt
  skipline
  read x    { x kommer til at indeholde alle 0-1 svarene }

  fac spm n 19         { spm = spørgsmålets nummer 1..19 }
  gen spm 1

  fac person n 112
  gen person 19       { person = personens nummer 1..112 }

  fac sex_l n 2
  get opg1 sex
  sex_l=sex(person)
  del sex
  ren sex_l sex                    { sex = personens køn }

  fac text_l n 5
  get opg1 text
  text_l=text(person)
  del text
  ren text_l text   { text = den tekst personen var udsat for }

  fac stud_l n 3
  get opg1 stud
  stud_l=stud(person)
  del stud
  ren stud_l stud             { stud = personens studium }

  save opg1lang